{
  self,
  nixpkgs,
  inputs,
}:

let
  mkSystem =
    systemConfig: name:
    nixpkgs.lib.nixosSystem rec {
      system =
        builtins.replaceStrings
          [
            "-unknown-"
            "-gnu"
          ]
          [
            "-"
            ""
          ]
          systemConfig;
      specialArgs = inputs;
      modules = [
        ./systems/${name}
        ./users/jopejoe1
        ./users/root
        ./users/fp
        ./common.nix
        self.inputs.disko.nixosModules.disko
        self.inputs.home-manager.nixosModules.home-manager
        self.inputs.nixos-generators.nixosModules.all-formats
        {
          system.stateVersion = "24.05";
          nixpkgs.hostPlatform = {
            system = system;
            config = systemConfig;
          };
          networking.hostName = name;
        }
      ];
    };
in
{
  pi400 = mkSystem "aarch64-unknown-linux-gnu" "pi400";
  pi4 = mkSystem "aarch64-unknown-linux-gnu" "pi4";
  pi5 = mkSystem "aarch64-unknown-linux-gnu" "pi5";
  pi4_2 = mkSystem "aarch64-unknown-linux-gnu" "pi4_2";
}