{
  self,
  nixpkgs,
  inputs,
}:

let
  mkSystem =
    systemConfig: name:
    nixpkgs.lib.nixosSystem rec {
      system =
        builtins.replaceStrings
          [
            "-unknown-"
            "-gnu"
          ]
          [
            "-"
            ""
          ]
          systemConfig;
      specialArgs = inputs;
      modules = [
        ./systems/${name}
        ./users/jopejoe1
        ./users/root
        ./users/fp
        ./common.nix
        self.inputs.disko.nixosModules.disko
        self.inputs.home-manager.nixosModules.home-manager
        self.inputs.nixos-generators.nixosModules.all-formats
        self.inputs.srvos.nixosModules.desktop
        {
          system.stateVersion = "24.05";
          nixpkgs.hostPlatform = {
            system = system;
            config = systemConfig;
          };
          networking.hostName = name;
        }
      ];
    };
in
{
  club-mate = mkSystem "aarch64-unknown-linux-gnu" "club-mate";
  mio-mio-mate = mkSystem "aarch64-unknown-linux-gnu" "mio-mio-mate";
  fritz-mate = mkSystem "aarch64-unknown-linux-gnu" "fritz-mate";
  flora-mate = mkSystem "aarch64-unknown-linux-gnu" "flora-mate";
}